《魔獸世界懷舊服》戰(zhàn)士宏有什么 戰(zhàn)士宏命令設(shè)置

戰(zhàn)士宏命令設(shè)置：戰(zhàn)士的專用宏大致分為兩種：一種是功能型，一種是整合型。功能宏根據(jù)當(dāng)前場(chǎng)合需要立刻施放該技能，如果此技能有裝備或姿態(tài)要求，則直接切換武器和姿態(tài)并施放技能

一、首先戰(zhàn)士比其他普通職業(yè)多出三種姿態(tài)：戰(zhàn)斗、防御及狂暴。有些技能只能在某種姿態(tài)下施放(例如攔截)，有些則可以二種姿態(tài)下使用(例如盾擊)，有些則任意狀態(tài)都可以使用(例如英勇打擊)。具體如下：

全部姿態(tài)：英勇打擊 破甲 戰(zhàn)斗怒吼 挑戰(zhàn)怒吼 挫志怒吼 破膽怒吼 順劈斬 血性狂暴 猛擊

戰(zhàn)斗姿態(tài)：沖鋒 壓制 雷霆一擊 橫掃攻擊 懲戒痛擊 反擊風(fēng)暴

防御姿態(tài)：嘲諷 盾牌格擋 復(fù)仇 繳械 盾墻

狂暴姿態(tài)：攔截 拳擊 旋風(fēng)斬 魯莽 狂暴之怒

戰(zhàn)斗+防御：撕裂 盾擊

戰(zhàn)斗+狂暴：斷筋 斬殺

戰(zhàn)士的專用宏大致分為兩種：一種是功能型，一種是整合型。

1、功能型

功能宏根據(jù)當(dāng)前場(chǎng)合需要立刻施放該技能，如果此技能有裝備或姿態(tài)要求，則直接切換武器和姿態(tài)并施放技能，快速反應(yīng)，節(jié)省操作。例如：

[盾墻]切換為主手武器+盾牌，切換到防御姿態(tài)并施放盾墻。需快速連按

#showtooltip 盾墻

/equipslot 16 主手武器名

/equip 盾牌名

/cast [nostance:2]防御姿態(tài);[stance:2]盾墻

適用：武器戰(zhàn)或狂暴戰(zhàn)PVP或PVE保命用。防戰(zhàn)平常就手拿盾牌處于防御姿態(tài)，所以不常用。

拓展：在下邊還可加入回血，例如術(shù)士糖或大紅、蘿卜等。

同樣適用于盾擊這種需要裝備盾牌且處于防御姿態(tài)的技能。

*提示：[]里邊是為此宏起的名稱，當(dāng)宏圖標(biāo)放入動(dòng)作條時(shí)，只能顯示出名稱的前2個(gè)漢字或4個(gè)英文字母。所以為宏起個(gè)簡(jiǎn)潔的名稱可以起到準(zhǔn)確提示的作用。

相似的功能型宏還有：

[懲擊]戰(zhàn)斗姿態(tài)下直接懲戒痛擊，非戰(zhàn)斗姿態(tài)則切成戰(zhàn)斗姿態(tài)施放懲戒痛擊，如此時(shí)怒氣不夠，則施放血性狂暴再懲戒痛擊。需快速連按

#showtooltip 懲戒痛擊

/cast [nostance:1]戰(zhàn)斗姿態(tài);[stance:1]懲戒痛擊

/cast [stance:1]血性狂暴

說明：MT團(tuán)本拉怪時(shí)，偶有OT后嘲諷失敗，用此宏可快速切換到戰(zhàn)斗姿態(tài)施放懲戒痛擊拉住仇恨。有時(shí)切換到戰(zhàn)斗姿態(tài)后沒有怒氣，所以將血性狂暴加入(而且加入了施放條件，血性狂暴只能在戰(zhàn)斗姿態(tài)下施放)。在意的可將血性狂暴那條刪除。

適用：防戰(zhàn)PVE團(tuán)本

[近身]非戰(zhàn)斗中戰(zhàn)斗姿態(tài)沖鋒，戰(zhàn)斗中則切換到狂暴姿態(tài)遠(yuǎn)距離攔截，近身則施放斷筋。

#showtooltip [stance:1]沖鋒;[stance:3]攔截

/cast [nostance:1,nocombat]戰(zhàn)斗姿態(tài);[nostance:3,combat]狂暴姿態(tài)

/cast [stance:1,nocombat]沖鋒;[stance:3,combat]攔截

/cast 斷筋

適用：PVP

應(yīng)幾個(gè)回復(fù)要求將此宏改動(dòng)一下，加入當(dāng)前為狂暴姿態(tài)處于非戰(zhàn)斗中直接攔截(需按Alt鍵)，同時(shí)戰(zhàn)斗中攔截加入鼠標(biāo)指向。

#showtooltip [stance:1]沖鋒;[stance:3]攔截

/cast [mod:alt,stance:3][@mouseover,harm,nodead,stance:3,combat][stance:3,combat]攔截;[nostance:1,nocombat]戰(zhàn)斗姿態(tài);[stance:1,nocombat]沖鋒;[nostance:3,combat]狂暴姿態(tài)

/cast 斷筋

[打斷]戰(zhàn)斗和防御姿態(tài)沒有盾則切狂暴姿態(tài)拳擊!有盾則用盾擊!就是要打斷施法。

#showtooltip [stance:3]拳擊;[stance:1/2,equipped:盾牌]盾擊

/stopcasting

/cast [stance:1/2,noequipped:盾牌]狂暴姿態(tài);[stance:1/2,equipped:盾牌]盾擊;[stance:3]拳擊

[壓制]當(dāng)前處于戰(zhàn)斗姿態(tài)能壓制就壓制，處于非戰(zhàn)斗姿態(tài)則先切換戰(zhàn)斗姿態(tài)再壓制。

#showtooltip 壓制

/cast [nostance:1]戰(zhàn)斗姿態(tài);[stance:1]壓制

2、整合型

整合宏是將不同姿態(tài)下的技能整合到一起，處于哪個(gè)姿態(tài)則施放哪個(gè)姿態(tài)下的技能。熟練應(yīng)用此種整合，可大大減少鍵位和動(dòng)作條圖標(biāo)位置。例如：

[大招]當(dāng)前處于戰(zhàn)斗姿態(tài)就施放反擊風(fēng)暴，防御姿態(tài)就施放盾墻，狂暴姿態(tài)就施放魯莽。節(jié)省二個(gè)鍵位。

#showtooltip [stance:1]反擊風(fēng)暴;[stance:2]盾墻;[stance:3]魯莽

/cast [stance:1]反擊風(fēng)暴;[stance:2]盾墻;[stance:3]魯莽

說明：這是一個(gè)典型的整合型宏。將三種姿態(tài)下的大招整合到一起。并且按照當(dāng)前姿態(tài)顯示圖標(biāo)。具體那些技能整合在一起可自行考慮更換。類似的還有：

[壓復(fù)旋]戰(zhàn)斗姿態(tài)下壓制，防御姿態(tài)下復(fù)仇，狂暴姿態(tài)下旋風(fēng)斬。節(jié)省二個(gè)鍵位。

#showtooltip [stance:1]壓制;[stance:2]復(fù)仇;[stance:3]旋風(fēng)斬

/cast [stance:1]壓制;[stance:2]復(fù)仇;[stance:3]旋風(fēng)斬

[斬嘲]防御姿態(tài)下嘲諷，戰(zhàn)斗或狂暴姿態(tài)下能斬殺則斬殺，并且都可以優(yōu)先對(duì)鼠標(biāo)指向施放。非戰(zhàn)斗中上馬。節(jié)省二個(gè)鍵位。

#showtooltip [stance:1/3]斬殺;[stance:2]嘲諷

/cast [@mouseover,harm,nodead,stance:1/3][stance:1/3]斬殺;[@mouseover,harm,nodead,stance:2][stance:2]嘲諷;[nocombat]迅捷白馬

[打斷]戰(zhàn)斗和防御姿態(tài)有盾則用盾擊，狂暴狀態(tài)下則用拳擊，并且都可以優(yōu)先對(duì)鼠標(biāo)指向施放。將打斷整合到一起，還加入了吃面包。節(jié)省二個(gè)鍵位。

#showtooltip [stance:1/2,equipped:盾牌]盾擊;[stance:3]拳擊

/cast [nocombat]魔法甜面包;[@mouseover,harm,nodead,stance:1/2,equipped:盾牌][stance:1/2,equipped:盾牌]盾擊;[@mouseover,harm,nodead,stance:3][stance:3]拳擊

說明：

戰(zhàn)士非戰(zhàn)斗中常用的就兩個(gè)，一個(gè)是上馬，一個(gè)是吃面包回復(fù)血量。

以上兩個(gè)宏利用非戰(zhàn)斗中多加入了一個(gè)技能，又節(jié)省了一個(gè)鍵位。就是不能直觀顯示圖標(biāo)，不喜歡的可以把上馬或吃面包綁定到其他技能上。猛擊是戰(zhàn)士少用且少有讀條技能，特別適合。

如果有上馬更換加速飾品、裝備要求，在我分享的圣騎士常用宏及詳解中有。

我常用的基本都是整合型，只要保證整合及按鍵合理，快速反應(yīng)切換姿態(tài)，技能自己選擇施放，能夠滿足應(yīng)對(duì)任何突發(fā)狀況。(需要注意的是切換姿態(tài)后會(huì)自動(dòng)切換掉主動(dòng)作條，所以整合宏和功能宏都不要放置在主動(dòng)作條上)

3、下面為我隆重推薦的整合宏(宏名稱前面是我該宏綁定的按鍵)：

鼠上[戰(zhàn)斗]切換到戰(zhàn)斗姿態(tài)并裝備雙手武器，戰(zhàn)斗姿態(tài)下則沖鋒，近身能壓制就壓制(需快速連按)。按住Ctrl鍵施放戰(zhàn)斗怒吼，按住Shift鍵則施放挫志怒吼，按住Alt鍵則施放順劈斬。

#showtooltip [nostance:1]戰(zhàn)斗姿態(tài);[stance:1]沖鋒

/cast [mod:ctrl]戰(zhàn)斗怒吼

/cast [mod:shift]挫志怒吼

/cast [mod:alt]順劈斬

/equip [exists]雙手武器名

/cast [nostance:1]戰(zhàn)斗姿態(tài);[stance:1,nocombat]沖鋒

/cast 壓制

鼠中[防御]切換到防御姿態(tài)，并裝備單手武器和盾牌，防御姿態(tài)下能復(fù)仇就打復(fù)仇。按住Ctrl鍵施放挑戰(zhàn)怒吼，按住Shift鍵則施放血性狂暴，按Alt鍵則施放破釜沉舟。

#showtooltip [nostance:2]防御姿態(tài);[stance:2]復(fù)仇

/cast [mod:ctrl]挑戰(zhàn)怒吼

/cast [mod:shift]血性狂暴

/cast [mod:alt]破釜沉舟

/equipslot 16 主手武器名

/equip 盾牌名

/cast [nostance:2]防御姿態(tài);[stance:2]復(fù)仇

鼠下[狂暴]切換到狂暴姿態(tài)，并裝備雙持武器，狂暴姿態(tài)下則攔截，近身能斬殺就斬殺(需快速連按)。按住Ctrl鍵施放破膽怒吼，按住Shift鍵則施放破甲，按Alt鍵則施放斷筋。

#showtooltip [nostance:3]狂暴姿態(tài);[stance:3]攔截

/cast [mod:ctrl]破膽怒吼

/cast [mod:shift]破甲

/cast [mod:alt]斷筋

/equipslot 16 主手武器名

/equipslot 17 副手武器名

/cast [nostance:3]狂暴姿態(tài);[stance:3]攔截

/cast 斬殺

說明：以上三個(gè)宏是我主要用來切換姿態(tài)的，在每個(gè)姿態(tài)下還都綁定了一個(gè)該姿態(tài)下的主要技能。

這里還根據(jù)姿態(tài)需要加入了武器更換，如果在意的可以自行刪掉該行。

并且利用Ctrl、Shift和Alt等輔助鍵另外各加了一些技能，最好配合WA等技能冷卻監(jiān)控插件。在意的可自行刪減。

*友情提示:盡量把所有姿態(tài)都能使用的技能綁定到加輔助鍵的這三個(gè)宏里，大量節(jié)省圖標(biāo)鍵位。具體技能自行考慮更換。

還需要注意的是這種綁定了Ctrl、Shift、Alt等組合鍵不要和游戲默認(rèn)按鍵沖突，否則宏無法執(zhí)行。例如： <Ctrl+1>是第一個(gè)宏物技能，<Shift+1>為第一個(gè)動(dòng)作條。把此宏放在1鍵上則無法正常執(zhí)行。

4、下面是一些普通常用的宏：

[斬殺]對(duì)當(dāng)前目標(biāo)開始攻擊，可以斬殺就斬殺。如果當(dāng)前目標(biāo)死亡，切換8碼內(nèi)的敵對(duì)目標(biāo)攻擊或斬殺。并且標(biāo)記為骷髏。

#showtooltip 斬殺

/targetenemy [noharm][harm,dead]

/script SetCVar("targetNearestDistance",8)

/startattack

/cast [harm,nodead]斬殺

/script SetRaidTarget("target",8)

說明：在日常PVE戰(zhàn)斗中需要頻繁切換目標(biāo)。此宏不需要鼠標(biāo)右鍵或TAB鍵選擇直接切換敵對(duì)目標(biāo)。同時(shí)加入自動(dòng)攻擊，節(jié)省操作。

倒數(shù)第二行的數(shù)字8代表距離8碼，如果實(shí)際操作覺得太近的話 可以自己改。比如10、15。。。

拓展：同樣適用于武器戰(zhàn)的致命打擊和狂暴戰(zhàn)的嗜血，也適用于其他技能，比如英勇等等將技能名稱更換即可。

還加入了標(biāo)記，方便小本配合。不喜歡的可自行刪掉最后一行。具體標(biāo)記編號(hào)如下：

[標(biāo)記]圖標(biāo)編號(hào) 0=取消圖標(biāo);1=黃色四角星;2=橙色圓形;3=紫色菱形;4=綠色三角;5=白色月亮;6=藍(lán)色方塊;7=紅色叉子;8=骷髏

/script SetRaidTarget("target",圖標(biāo)編號(hào));

[斷遠(yuǎn)]近身撕裂，遠(yuǎn)程則射擊或投擲。

#showtooltip

/startattack

/cast 撕裂

/cast [equipped:投擲武器]投擲

/cast [equipped:弓]弓射擊

/cast [equipped:弩]弩射擊

/cast [equipped:槍械]槍械射擊

說明：自動(dòng)根據(jù)身上裝備的遠(yuǎn)程武器遠(yuǎn)程射擊。還加入了近戰(zhàn)攻擊，節(jié)省操作。

[破吼]非戰(zhàn)斗中只為自己打繃帶。戰(zhàn)斗中則立刻施放破膽怒吼并停止攻擊，并為自己打上繃帶。需快速連按。

#showtooltip 破膽怒吼

/stopattack

/cast [combat]破膽怒吼

/use [@player]厚符文布繃帶

說明：默認(rèn)施放破膽怒吼會(huì)因?yàn)樽詣?dòng)攻擊當(dāng)前目標(biāo)而打斷繃帶。第二行加入停止近戰(zhàn)攻擊則避免此種情況，最后一行加入繃帶，最快速為自己回血。保命必用。

[報(bào)血]只有在有隊(duì)伍時(shí)，吃面包并在隊(duì)伍中說出當(dāng)前血量百分比。如需沒有隊(duì)伍也可通報(bào)，可將 /stopmacro [nogroup:party]此行刪掉。此宏是網(wǎng)上借用的。

#showtooltip

/use 嫩狼肉排

/use 魔法甜面包

/use 奧特蘭克魔法點(diǎn)心

/stopmacro [nogroup:party]

/run c=string.format("%d", UnitHealth("player")/ UnitHealthMax("player")*100) SendChatMessage(c.."% 面包回血中……", "party",nil, 1)

[專業(yè)]專業(yè)整合用：按擊打開鍛造，加Ctrl鍵為工程學(xué)，加Shift鍵為烹飪，加Alt鍵為急救。

#showtooltip

/cast [mod:ctrl]工程學(xué);[mod:shift]烹飪;[mod:alt]急救;鍛造

關(guān)于專業(yè)技能整合的宏還有另外一種形式，例如：

[吃喝]按擊或鼠標(biāo)左鍵點(diǎn)擊打開鍛造，鼠標(biāo)右鍵為工程學(xué)。<Ctrl+左鍵>烹飪，<Ctrl+右鍵>急救。

#showtooltip

/cast [mod:ctrl,button:1]烹飪

/cast [mod:ctrl,button:2]急救

/cast [mod:shift,button:1]

/cast [mod:shift,button:2]

/cast [mod:alt,button:1]

/cast [mod:alt,button:2]

/cast [button:1]鍛造

/cast [button:2]工程學(xué)

說明：這種宏操作沒有上一個(gè)宏簡(jiǎn)練，需要鼠標(biāo)操作。優(yōu)點(diǎn)是可以綁定更多的技能，比如各種吃喝、藥劑。將相應(yīng)的技能名替換即可。

戰(zhàn)士在PVE團(tuán)本中，有時(shí)還需要取消圣騎士的一些BUFF操作。(由于本人本命職業(yè)為圣騎士，所以對(duì)此特別關(guān)注)

CancelAura 強(qiáng)效拯救祝福

CancelAura 拯救祝福

CancelAura 保護(hù)祝福

以上三條分別為取消強(qiáng)效拯救祝福，拯救祝福和保護(hù)祝福?？梢晽l件分別和其它技能綁定或整合為一個(gè)宏。

5、再分享一些比較實(shí)用的命令：

[聊天窗口顯示職業(yè)顏色]0顯示/1不顯示 /console SET chatClassColorOverride "0"根據(jù)聊天判斷職業(yè)，方便加BUFF

[死亡灰色特效]0關(guān)閉/1開啟 /console ffxDeath 0死亡釋放以后會(huì)有灰色特效，陰森恐怖死氣沉沉。關(guān)閉以后一切又恢復(fù)五彩繽紛、生機(jī)勃勃。

[重置副本] /run ResetInstances()刷副本常用命令，再加入喊話，方便快捷。

[隱藏動(dòng)作條兩邊獅鷲] 左/右 /script MainMenuBarLeftEndCap:Hide() /script MainMenuBarRightEndCap:Hide()

[最大鏡頭距離]1-2.6 /console CameraDistanceMaxZoomFactor 2.6

[改TAB距離]身前/身后 0-50碼 /console SET targetNearestDistance "50" /console SET targetNearestDistanceRadius "50"

以上就是魔獸世界懷舊服戰(zhàn)士宏命令設(shè)置的全部?jī)?nèi)容了，希望給大家?guī)韼椭?/p>